Visual Basic interdit l'héritage multiple, mais l'encapsulation permet, utilisée avec méthode, d'obtenir un résultat équivalent. Héritage et encapsulation sont deux piliers de la programmation orientée objet, plus faciles à saisir par l'exemple que par la définition.
Les deux techniques visent le même but : étendre les fonctionnalités d'un code existant. On dérive une nouvelle classe par héritage, puis on encapsule les classes secondaires.
Créer le projet et la classe Customer
Ouvrez Visual Studio et créez une application console nommée MultiClassDemo. Ajoutez une classe Customer via « Projet », « Nouvelle classe » :
Public Class Customer
Public Property CustomerID As String = ""
Public Property CompanyName As String = ""
Public Property Contact As String = ""
Public Overridable Sub Load(ByVal id As String)
CustomerID = id
CompanyName = "Location Acme"
Contact = "Joe Smith"
End Sub
End Class
Cette classe décrit un client avec ses propriétés d'identifiant, de société et de contact ; la méthode Load leur affecte des valeurs.
Créer la classe Credit
Répétez l'opération :
Public Class Credit
Public Property CustomerID As String = ""
Public Property CreditScore As String = ""
Public Property ReportDate As Date = Date.MinValue
Public Sub Load(ByVal id As String)
CustomerID = id
CreditScore = "A+"
ReportDate = #6/1/2011#
End Sub
End Class
Dériver une troisième classe
Créez CustomerCredit et faites-la hériter de Customer :
Public Class CustomerCredit
Inherits Customer
À la compilation, cette classe hérite des propriétés CustomerID, CompanyName et Contact, ainsi que de la méthode Load de la classe Customer.
Encapsuler Credit
Ajoutez un champ privé contenant une instance de Credit :
Private score As New Credit
Puis exposez ses propriétés au moyen de propriétés dérivées :
Public Property CreditScore As String
Get
Return score.CreditScore
End Get
Set(ByVal value As String)
score.CreditScore = value
End Set
End Property
Public Property ReportDate As Date
Get
Return score.ReportDate
End Get
Set(ByVal value As Date)
score.ReportDate = value
End Set
End Property
Moins commode que l'héritage multiple, cette délégation expose néanmoins les propriétés de crédit.
Surcharger Load
Redéfinissez la méthode pour charger les deux jeux de propriétés :
Public Overrides Sub Load(ByVal id As String)
MyBase.Load(id)
score.Load(id)
End Sub
End Class
Tester
Dans Module1, écrivez :
Module Module1
Sub Main()
Dim cust As New CustomerCredit
cust.Load("1234")
Console.WriteLine("Client = " & cust.CustomerID)
Console.WriteLine("Société : " & cust.CompanyName)
Console.WriteLine("Contact : " & cust.Contact)
Console.WriteLine("Credit Score : " & cust.CreditScore)
Console.WriteLine("Date du rapport : " & cust.ReportDate.ToShortDateString)
End Sub
End Module
Appuyez sur F5 : les cinq informations s'affichent, preuve que la combinaison héritage plus encapsulation fonctionne.